Langkau ke kandungan utama
Projek ini dalam fasa beta. Jumpa pepijat? Buat isu GitHub. Ada soalan atau idea? Tanya dalam Discussions — kami suka dengar maklum balas anda!
Bagaimana kualiti terjemahan pada halaman ini?

Pelajari keadaan kuantum bernoise dengan bayang klasik

Anggaran penggunaan: 34 minit pada pemproses Heron r2 (NOTA: Ini hanya anggaran. Masa larian anda mungkin berbeza.)

Hasil pembelajaran​

  • Kumpulkan pengukuran rawak pada pemproses kuantum IBM® daripada Julia dan simpannya untuk analisis kemudian

  • Semak data pengukuran untuk qubit dan gate yang rosak sebelum pembelajaran

  • Padankan model operator hasil darab matriks (MPO) bagi keadaan bernoise kepada bayang klasik

  • Sahkan model pada pengukuran yang ditahan dan bandingkannya dengan litar unggul

Prasyarat​

Latar belakang​

Pada pemproses kuantum sebenar, noise menukarkan keadaan tulen ∣ψ⟩|\psi\rangle yang litar direka untuk disediakan kepada keadaan bercampur ρ\rho. Tomografi keadaan kuantum penuh boleh membina semula ρ\rho, tetapi bilangan pengukuran yang diperlukannya bertambah secara eksponen dengan bilangan qubit. Votto et al. [1] sebaliknya mempelajari model padat bagi ρ\rho sehingga 96 qubit daripada pengukuran rawak. Tutorial ini mengikuti aliran kerja mereka.

Dalam pengukuran rawak [2], setiap qubit ii diputar oleh unitari rawak bebas uiu_i dan kemudian diukur dalam asas pengiraan. Satu cabutan putaran dipanggil tetapan pengukuran, dan setiap tetapan diulang untuk NMN_M tembakan. Tembakan dengan bit hasil sis_i memberikan bayang klasik [3]

ρ^=⨂i=1N(3 ui†∣si⟩⟨si∣ui−1),\hat\rho=\bigotimes_{i=1}^{N}\left(3\,u_i^\dagger|s_i\rangle\langle s_i|u_i-\mathbb{1}\right),

yang purata ke atas tetapan dan tembakan ialah ρ\rho. Tutorial prasyarat mencabut setiap uiu_i daripada tiga asas Pauli; tutorial ini, seperti kertas kajian itu, mencabutnya secara seragam daripada semua unitari qubit tunggal (rawak Haar), dan formula yang sama terpakai.

Bayang menganggar sifat beberapa qubit pada satu masa. Kertas kajian itu menggabungkannya menjadi operator hasil darab matriks (MPO), yang menulis matriks ketumpatan sebagai rantaian tensor kecil, satu bagi setiap qubit; keadaan bernoise dengan korelasi jarak pendek hanya memerlukan ikatan kecil antara tensor bersebelahan. Seperti algoritma kumpulan penormalan semula matriks ketumpatan (DMRG), pembelajar menyapu sepanjang rantaian dan mengemas kini satu tensor pada satu masa, supaya model sepadan dengan bayang pada tetingkap 2ℓ+12\ell+1 qubit yang berpusat pada tensor itu (Persamaan 4 dalam kertas kajian). Dimensi ikatan kekal tetap semasa kemas kini ini, jadi pembelajar tidak pernah memangkas model. Oleh sebab data hanya masuk melalui tetingkap ini, bilangan tetapan yang diperlukan tidak bertambah dengan panjang rantaian.

Tetapan dibahagikan kepada set latihan dan set ujian. Pada set ujian, kertas kajian itu menganggar kesetiaan maksimum antara ρ\rho dan model σ\sigma,

Fmax⁡(ρ,σ)=tr(ρσ)max⁡(tr ρ2, tr σ2).\mathcal{F}_{\max}(\rho,\sigma)=\frac{\mathrm{tr}(\rho\sigma)}{\max\left(\mathrm{tr}\,\rho^2,\ \mathrm{tr}\,\sigma^2\right)}.

Mengukur tr(ρσ)\mathrm{tr}(\rho\sigma) secara langsung memerlukan pengukuran yang banyaknya eksponen. Sebaliknya, kertas kajian itu mengandaikan syarat pemfaktoran hampir (AFC): korelasi dalam ρ\rho susut dalam beberapa qubit, jadi pertindihan dan ketulenan global difaktorkan kepada sebutan pada blok kk qubit bersebelahan. Ketulenan juga memberikan entropi Rényi-2 S2=−log⁡2tr ρ2S_2=-\log_2\mathrm{tr}\,\rho^2, yang mengukur sejauh mana keadaan itu bercampur.

Kertas kajian itu menyediakan keadaan Ising bertendang berkedalaman DD

∣ψ⟩=(∏jeiπ4ZjZj+1∏je−iπ8Xj)D∣0⟩⊗N|\psi\rangle=\left(\prod_{j} e^{i\frac{\pi}{4}Z_jZ_{j+1}}\prod_j e^{-i\frac{\pi}{8}X_j}\right)^{D}|0\rangle^{\otimes N}

pada 96 qubit ibm_brisbane, pemproses Eagle, dengan 2,048 tetapan 1,024 tembakan untuk D=1D=1. Rajah 1(c,d) kertas kajian itu melaporkan dua hasil untuk D=1D=1:

  • Model yang dipelajari mencapai Fmax⁡≈75%\mathcal{F}_{\max}\approx 75\% dengan keadaan eksperimen pada N=96N=96, jauh melebihi pertindihan keadaan unggul ∣ψ⟩|\psi\rangle dengan eksperimen.

  • Entropi bertambah secara linear, S2≈(0.14 hingga 0.15) NS_2\approx(0.14\text{ hingga }0.15)\,N, dan entropi model sepadan dengan anggaran bebas daripada set ujian.

Tutorial ini menyemak kedua-dua hasil, pertama dalam simulasi lapan qubit di mana jawapan tepat diketahui, dan kemudian dalam larian 96 qubit baharu pada ibm_fez, pemproses Heron r2. Pembelajar ialah pelaksanaan Julia bebas bagi persamaan dalam kertas kajian dan suplemennya.

Keperluan​

Tutorial ini memerlukan macOS atau Linux, kerana Qiskit.jl belum menyokong Windows (isu Qiskit.jl #15). Anda juga memerlukan yang berikut:

  • Julia 1.11, daripada halaman muat turun Julia atau dengan juliaup add 1.11, dan pakej IJulia:

    julia -e 'using Pkg; Pkg.add("IJulia")'
  • Untuk contoh perkakasan, akaun IBM Quantum® Platform dengan akses kepada QPU yang mempunyai sekurang-kurangnya 96 qubit, dan bukti kelayakan yang disimpan. Tanpa akaun, anda boleh menjalankan contoh perkakasan daripada pengukuran tersimpan bagi larian ibm_fez yang menghasilkan keputusan dalam tutorial ini. Bahagian lain berjalan tanpa akaun.

Buku nota ini menggunakan Qiskit.jl dan QiskitIBMRuntime.jl untuk membina dan menjalankan litar, RandomMeas.jl [4] untuk pengukuran rawak (ia juga menyediakan ITensors.jl dan ITensorMPS.jl), serta NPZ.jl, JSON.jl, dan Plots.jl. Tutorial ini diuji dengan Qiskit.jl 0.6.1, QiskitIBMRuntime.jl 0.3.2, dan RandomMeas.jl 0.3.1.

Terdapat dua cara untuk menyediakan persekitaran:

  • Pilihan 1: Pasang versi terkini yang serasi bagi pakej ke dalam persekitaran sementara. Jalankan sel berikut tanpa perubahan.

  • Pilihan 2: Hasilkan semula persekitaran yang diuji dengan tepat. Tetapkan download_toml_files = true dalam sel berikut. Sel ini memuat turun Project.toml dan Manifest.toml daripada repositori dokumentasi ke dalam folder env_tutorial/classical-shadows/ bersebelahan buku nota ini, kemudian memasang versi tepat bagi setiap pakej yang direkodkan oleh manifes, termasuk kebergantungan tidak langsung. Untuk butiran, lihat dokumentasi Julia tentang fail ini.

using Pkg
using Downloads

download_toml_files = false

if !download_toml_files
# Option 1: Install the latest compatible versions into a temporary environment
Pkg.activate(mktempdir(); io=devnull)
Pkg.add([
PackageSpec(name="Qiskit", version="0.6"),
PackageSpec(name="QiskitIBMRuntime", version="0.3"),
PackageSpec(name="RandomMeas", version="0.3"),
PackageSpec(name="NPZ"),
PackageSpec(name="JSON"),
PackageSpec(name="Plots"),
]; io=devnull)
else
# Option 2: Install the exact tested versions recorded in Project.toml and Manifest.toml
base_url = "https://raw.githubusercontent.com/Qiskit/documentation/main/docs/tutorials/assets/classical-shadows/julia"
env_dir = joinpath(@__DIR__, "env_tutorial", "classical-shadows")
mkpath(env_dir)
for file in ("Project.toml", "Manifest.toml")
Downloads.download("$base_url/$file", joinpath(env_dir, file))
end
Pkg.activate(env_dir; io=devnull)
Pkg.instantiate(; io=devnull)
end

Persediaan​

using RandomMeas # also loads ITensors and ITensorMPS
using Qiskit, QiskitIBMRuntime
using Random, LinearAlgebra, Statistics
using Downloads, SHA, NPZ, JSON, Plots

# Download the helper module that implements the learner, unless a copy exists
docs_url = "https://raw.githubusercontent.com/Qiskit/documentation/main"
helper_file = joinpath(@__DIR__, "env_tutorial", "classical-shadows", "mpo_learning.jl")
if !isfile(helper_file)
mkpath(dirname(helper_file))
helper_url = "$docs_url/docs/tutorials/assets/classical-shadows/julia/mpo_learning.jl"
Downloads.download(helper_url, helper_file)
end
include(helper_file)
using .ShadowMPOLearning
BLAS.set_num_threads(1) # the learner multiplies many small matrices

Modul pembantu mpo_learning.jl, yang dimuat turun oleh sel Persediaan, melaksanakan pembelajar. Tutorial ini memanggil fungsi berikut daripadanya:

FungsiTujuan
kicked_ising_reference(N, D; depolarization)MPO tepat bagi keadaan Ising bertendang unggul, atau bagi keadaan selepas noise penyahkutuban setempat
split_settings(group; seed, train_fraction)Menetapkan tetapan pengukuran secara rawak kepada set latihan dan ujian (separuh setiap satu secara lalai)
training_marginals(train; ell, prior)Anggaran bayang bagi setiap tetingkap pembelajaran, daripada tetapan latihan sahaja
fitted_prior(ideal, train)Prior untuk pengukuran rawak biasa (CRM), dipadankan dengan ketulenan terukur bagi setiap tetingkap, seperti dalam kertas kajian
learn_mpo(marginals, N; ell, maxbond, sweeps)Menyapu kemas kini satu tapak daripada kertas kajian sepanjang rantaian, bermula daripada keadaan bercampur maksimum
max_fidelity(a, b), mpo_overlap(a, b)Fmax⁡\mathcal{F}_{\max} dan tr(ab)\mathrm{tr}(ab) tepat antara dua MPO
afc_estimate, afc_statistics, afc_prefix_curveAnggaran AFC bagi Fmax⁡\mathcal{F}_{\max} dan S2S_2 daripada tetapan ujian, dengan bar ralat jackknife

Pembelajar menyimpan MPO dalam asas Pauli. Ini mengekalkan model Hermitian dengan surih unit, tetapi tidak memaksa model menjadi separa tentu positif, jadi buku nota melaporkan sejauh mana nilai eigennya menjadi negatif.

Contoh simulator berskala kecil​

Mulakan dengan sistem yang cukup kecil untuk mengira segala-galanya dengan tepat: keadaan Ising bertendang berkedalaman satu pada lapan qubit, dengan noise penyahkutuban setempat 12% untuk memodelkan perkakasan. Oleh sebab keadaan bernoise itu diketahui, anda boleh membandingkan model yang dipelajari dengannya secara langsung.

Langkah 1: Petakan input klasik kepada masalah kuantum​

Fungsi kicked_ising_reference mengembalikan keadaan tepat sebagai MPO. Dengan depolarization=0.12, vektor Bloch setiap qubit mengecut 12% selepas litar.

N = 8
ideal = kicked_ising_reference(N, 1)
rho = kicked_ising_reference(N, 1; depolarization=0.12)
println("Purity of the noisy state: ", round(mpo_overlap(rho, rho), digits=3))
println("F_max between the noisy and ideal states: ", round(max_fidelity(rho, ideal), digits=3))
Purity of the noisy state: 0.327
F_max between the noisy and ideal states: 0.56

Langkah 2: Optimumkan masalah untuk pelaksanaan pada perkakasan kuantum​

Contoh ini mensampel hasil pengukuran secara klasik, jadi tiada litar untuk ditranspil. Contoh perkakasan merangkumi langkah ini.

Langkah 3: Laksanakan menggunakan primitif Qiskit​

Gunakan RandomMeas.jl untuk mencabut 2,048 tetapan pengukuran rawak Haar dan mensampel 256 tembakan daripada setiap satu, kemudian bahagikan tetapan secara sama rata kepada set latihan dan ujian. Bahagikan mengikut tetapan dan bukan mengikut tembakan: tembakan daripada tetapan yang sama berkongsi putarannya, jadi ia tidak bebas.

Random.seed!(20260921)
sites = siteinds("Qubit", N)
settings = [LocalUnitaryMeasurementSetting(N; site_indices=sites, ensemble=Haar) for _ in 1:2048]
measurements = MeasurementGroup(to_itensor_mpo(rho, sites), settings, 256)
split = split_settings(measurements; seed=20260921)
println(length(split.train_ids), " training settings, ", length(split.test_ids), " testing settings")
1024 training settings,
1024 testing settings

Langkah 4: Pasca-proses dan kembalikan hasil dalam format klasik yang dikehendaki​

Pelajari model dengan parameter berkedalaman satu kertas kajian: tetingkap yang melanjutkan ℓ=2\ell=2 qubit pada setiap sisi tensor yang dikemas kini, dimensi ikatan 4, dan 20 sapuan bermula daripada keadaan bercampur maksimum. Sapuan pertama mengemas kini pasangan tensor bersebelahan, yang membolehkan dimensi ikatan membesar daripada 1 kepada 4; setiap sapuan seterusnya mengemas kini satu tensor pada satu masa pada dimensi ikatan tetap itu.

Untuk mengurangkan noise statistik bayang, kertas kajian itu menggunakan pengukuran rawak biasa (CRM) [5]. Bagi setiap tetapan, ia menolak bayang purata yang akan dihasilkan oleh tekaan prior keadaan dalam tetapan yang sama, kemudian menambah semula nilai tepat prior itu. Pembetulan ini puratanya sifar, jadi prior mengubah saiz ralat statistik tetapi bukan apa yang dianggarkan. Di sini prior ialah keadaan unggul dengan penyahkutuban setempat 10%, hampir dengan 12% sebenar. Pada perkakasan, tahap noise tidak diketahui, jadi contoh perkakasan memadankan prior kepada ketulenan terukur, seperti yang dilakukan kertas kajian itu.

prior = kicked_ising_reference(N, 1; depolarization=0.10)
marginals = training_marginals(split.train; ell=2, prior)
fit = learn_mpo(marginals, N; ell=2, maxbond=4, sweeps=20)
sigma = fit.model
plot([h.sweep for h in fit.history], [h.local_loss for h in fit.history];
xlabel="sweep", ylabel="mean squared residual", label="training windows",
size=(680, 320), left_margin=5Plots.mm, bottom_margin=5Plots.mm)

Output of the previous code cell

Reja mengukur sejauh mana tetingkap model daripada bayang latihan. Ia menurun apabila kemas kini satu tapak bermula, pada sapuan kedua, dan kemudian kekal hampir malar dan tidak mencapai sifar, kerana bayang mengandungi noise statistik yang tidak dapat dihasilkan semula oleh model dengan dimensi ikatan kecil.

Oleh sebab keadaan ini diketahui, anda boleh membandingkan model yang dipelajari dengannya secara tepat, dan juga membandingkan dua tekaan paling ringkas dengannya: prior CRM dan keadaan unggul.

eigenvalues = eigvals(Hermitian(dense_operator(sigma)))
println("F_max with the noisy state")
println(" learned model: ", round(max_fidelity(rho, sigma), digits=3))
println(" CRM prior: ", round(max_fidelity(rho, prior), digits=3))
println(" ideal state: ", round(max_fidelity(rho, ideal), digits=3))
println("Most negative eigenvalue of the model: ", round(minimum(eigenvalues), digits=4))
println("Total negative eigenvalue weight: ", round(-sum(min.(eigenvalues, 0)), digits=4))
F_max with the noisy state
learned model: 0.993
CRM prior: 0.911
ideal state: 0.56
Most negative eigenvalue of the model: -0.0076
Total negative eigenvalue weight: 0.0348

Model yang dipelajari lebih dekat dengan keadaan bernoise berbanding prior atau keadaan unggul, jadi ia telah mempelajari noise daripada data. Nilai eigen negatifnya yang kecil datang daripada bilangan pengukuran yang terhad.

Pada perkakasan, keadaan tidak diketahui, jadi anda menganggar Fmax⁡\mathcal{F}_{\max} daripada tetapan ujian. AFC membahagikan rantaian kepada blok A1,…,ARA_1,\dots,A_R yang masing-masing kk qubit dan menghampiri ketulenan dengan

tr ρ2≈∏i=1R−1tr ρAiAi+12∏i=2R−1tr ρAi2,\mathrm{tr}\,\rho^2\approx\frac{\prod_{i=1}^{R-1}\mathrm{tr}\,\rho_{A_iA_{i+1}}^2}{\prod_{i=2}^{R-1}\mathrm{tr}\,\rho_{A_i}^2},

dan tr(ρσ)\mathrm{tr}(\rho\sigma) dengan nisbah pertindihan setempat yang sama. Dengan k=4k=4, kedua-dua blok meliputi kesemua lapan qubit dan formula itu tepat; dengan k=2k=2, ia bergantung pada andaian pemfaktoran. Bar ralat jackknife, yang mengecualikan satu tetapan ujian pada satu masa, hanya meliputi ralat statistik data ujian, bukan kerawakan latihan atau penghampiran AFC.

for k in (2, 4)
estimate = afc_estimate(sigma, split.test; k, statistics=afc_statistics(split.test, k; prior))
println("k = $k: held-out F_max = ", round(estimate.fidelity, digits=3), " ± ",
round(estimate.fidelity_sem, digits=3))
end
println("Exact F_max: ", round(max_fidelity(rho, sigma), digits=3))
k = 2: held-out F_max = 0.966
± 0.036
k = 4: held-out F_max =
0.958 ± 0.049
Exact F_max: 0.993

Kedua-dua anggaran yang ditahan sepadan dengan nilai tepat dalam bar ralat masing-masing.

Contoh perkakasan berskala besar​

Kini jalankan eksperimen pada rantaian 96 qubit ibm_fez, pemproses Heron r2. Seperti ibm_brisbane, ia mempunyai peta gandingan heavy-hex dan tahap noise yang serupa.

Mengumpulkan data memerlukan 1,024 tugas Sampler dan kira-kira 34 minit masa QPU. Jika anda tiada akses kepada QPU dengan sekurang-kurangnya 96 qubit, atau barisan gilirannya panjang, jalankan contoh perkakasan daripada pengukuran yang direkodkan pada ibm_fez pada 27 September 2026, yang menghasilkan keputusan yang ditunjukkan dalam tutorial ini. Dengan use_saved_data = true, buku nota memuat turun pengukuran ini (15 MB) daripada Zenodo [6] dalam Langkah 1 dan melangkau penghantaran tugas dalam Langkah 3. Untuk mengumpulkan data anda sendiri, tetapkannya kepada false.

use_saved_data = true; # set to false to collect new measurements on hardware

Langkah 1: Petakan input klasik kepada masalah kuantum​

Setiap tetapan memerlukan satu litar: litar Ising bertendang, gate U(θ,ϕ,λ)U(\theta,\phi,\lambda) pada setiap qubit untuk uiu_i, dan pengukuran bagi setiap qubit. Mensampel θ=2arcsin⁡v\theta=2\arcsin\sqrt{v}, dengan vv, ϕ/2π\phi/2\pi, dan λ/2π\lambda/2\pi seragam dalam [0,1)[0,1), menjadikan UU rawak Haar. Fungsi u3_matrix mengembalikan matriks UU, yang digunakan oleh Langkah 4.

Bajetnya ialah 1,024 tetapan dengan 1,024 tembakan, separuh daripada bilangan tetapan dalam kertas kerja itu, dibahagikan sama rata antara latihan dan ujian. Dengan data tersimpan, sel memuatkan sudut yang direkodkan. Jika tidak, sel menjana sudut baharu dan menyimpannya sebelum anda menghantar apa-apa, kerana anda tidak dapat menganalisis hasil tanpanya. Jika fail itu sudah wujud, sel memuatkannya, supaya sudut masih sepadan dengan hasil tersimpan selepas anda memulakan semula sesi.

"Matrix of the U(θ, ϕ, λ) gate, as used by `qc.u` in Qiskit."
u3_matrix(θ, ϕ, λ) = [cos(θ/2) -exp(im*λ)*sin(θ/2);
exp(im*ϕ)*sin(θ/2) exp(im*(ϕ + λ))*cos(θ/2)]

"Angles (θ, ϕ, λ) for which `u3_matrix(θ, ϕ, λ)` is a Haar-random unitary."
random_u3_angles() = (2asin(sqrt(rand())), 2π*rand(), 2π*rand())

N_hw, NU_hw, NM_hw = 96, 1024, 1024
data_directory = joinpath(@__DIR__, "classical-shadows-data")
saved_file = joinpath(data_directory, "ibm-fez-run.npz")
run_directory = joinpath(data_directory, "new-run")
settings_file = joinpath(run_directory, "settings.npz")
if use_saved_data
saved_url = "https://zenodo.org/records/24116174/files/ibm-fez-run.npz?download=1"
saved_sha256 = "c42f4d8d42e5083e9e152b4fec0846884ebe3be003e5ab528deebf4f00c9fe50"
if !isfile(saved_file)
mkpath(data_directory)
println("Downloading the saved ibm_fez run (15 MB)...")
Downloads.download(saved_url, saved_file * ".part")
mv(saved_file * ".part", saved_file)
end
bytes2hex(open(sha256, saved_file)) == saved_sha256 ||
error("$saved_file is incomplete or corrupted; delete it and run this cell again")
saved_run = npzread(saved_file)
angles = saved_run["angles"]
elseif isfile(settings_file)
angles = npzread(settings_file)["angles"]
else
mkpath(joinpath(run_directory, "outcomes"))
Random.seed!(20260927)
angles = Array{Float64}(undef, NU_hw, N_hw, 3)
for r in 1:NU_hw, i in 1:N_hw
angles[r, i, :] .= random_u3_angles()
end
npzwrite(settings_file, Dict("angles" => angles))
end
println("Measurement settings: ", size(angles, 1), " × ", size(angles, 2), " qubits")
Measurement settings: 1024
× 96 qubits

Langkah 2: Optimumkan masalah untuk pelaksanaan perkakasan kuantum​

Sebuah rantai hanya sebaik qubit yang paling lemah, jadi pilih sendiri 96 qubit fizikal. Fungsi transpile bagi Qiskit.jl belum boleh menerima susun atur awal yang tetap, dan dalam ujian pada ibm_phoenix, susun atur yang dipilihnya termasuk sebuah qubit dengan ralat bacaan 51%. Rantai berikut ialah laluan 96 qubit dalam peta gandingan ibm_fez yang dipilih oleh susun atur sedar-ralat bagi fungsi transpile Qiskit Python (dengan optimization_level=3) daripada data penentukuran pada 27 September 2026. Min ralat bacaannya ialah 1.6%, tetapi kekisi heavy-hex mempunyai sedikit laluan 96 qubit, dan laluan ini termasuk qubit 35, yang mempunyai ralat bacaan 15%. Penentukuran berubah, jadi pilih rantai baharu daripada data penentukuran semasa sebelum anda menjalankan pada hari atau QPU lain.

Untuk mengekalkan rantai ini, tulis litar terus dalam gate asli dan bukannya mentranspilnya. Sebuah gate U(θ,ϕ,λ)U(\theta,\phi,\lambda) sama dengan RZ(ϕ+π) X RZ(θ+π) X RZ(λ)R_Z(\phi+\pi)\,\sqrt{X}\,R_Z(\theta+\pi)\,\sqrt{X}\,R_Z(\lambda) sehingga fasa global. Penguraian ini merangkumi putaran rawak dan tendangan e−iπ8X=U(π/4,−π/2,π/2)e^{-i\frac{\pi}{8}X}=U(\pi/4,-\pi/2,\pi/2). Gate eiπ4ZjZj+1e^{i\frac{\pi}{4}Z_jZ_{j+1}} sama dengan gate CZ diikuti S†S^\dagger pada kedua-dua qubit, sehingga fasa global. Oleh sebab gate S†S^\dagger ini bersifat pepenjuru, ia kalis tukar tertib dengan gate CZ, jadi setiap qubit mengumpul satu RZ(−π/2)R_Z(-\pi/2) bagi setiap ikatan sebelum putaran pengukurannya.

num_device_qubits = 156
# Physical qubits of ibm_fez, in IBM numbering, forming the chain
chain_physical = [
2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 19, 35, 34, 33, 39, 53, 54, 55, 59, 75, 74,
73, 79, 93, 94, 95, 99, 115, 114, 113, 119, 133, 132, 131, 130, 129, 128, 127, 137, 147, 146,
145, 144, 143, 136, 123, 124, 125, 117, 105, 106, 107, 108, 109, 110, 111, 98, 91, 90, 89,
88, 87, 86, 85, 77, 65, 66, 67, 68, 69, 70, 71, 58, 51, 50, 49, 48, 47, 46, 45, 37, 25, 24,
23, 22, 21, 36, 41, 42, 43, 56, 63]
chain = chain_physical .+ 1 # Qiskit.jl numbers qubits from 1

"Apply U(θ, ϕ, λ) to qubit q with native gates: rz(λ), sx, rz(θ + π), sx, rz(ϕ + π)."
function native_u!(qc, q, θ, ϕ, λ)
qc.rz(λ, q)
qc.sx(q)
qc.rz(θ + π, q)
qc.sx(q)
qc.rz(ϕ + π, q)
end

"Kicked-Ising circuit on `chain`, then the rotations of one setting and a measurement."
function native_setting_circuit(chain, angles, num_device_qubits)
n = length(chain)
qc = QuantumCircuit(num_device_qubits, n)
for q in chain
native_u!(qc, q, π/4, -π/2, π/2) # e^{-iπ/8 X}
end
for i in 1:n-1
qc.cz(chain[i], chain[i + 1]) # e^{iπ/4 ZZ}, up to the S† gates below
end
for (i, q) in enumerate(chain)
bonds = (i > 1) + (i < n)
qc.rz(-π/2 * bonds, q) # one S† per bond
native_u!(qc, q, angles[i, 1], angles[i, 2], angles[i, 3])
qc.measure(q, i) # outcome of chain qubit i goes to bit i
end
qc
end

circuits = [native_setting_circuit(chain, angles[r, :, :], num_device_qubits) for r in 1:NU_hw]
println(length(circuits), " circuits, each with ", count(inst -> inst.name == "cz", circuits[1].data), " CZ gates")
1024 circuits, each with
95 CZ gates

Langkah 3: Laksanakan menggunakan primitif Qiskit​

QiskitIBMRuntime.jl menjalankan satu litar bagi setiap job Sampler, jadi pengumpulan data memerlukan 1,024 job. Sel berikut mengekalkan sehingga 32 job dalam giliran dan menyimpan hasil bagi setiap tetapan sebaik sahaja job-nya selesai. Setiap tembakan dikembalikan sebagai vektor bit, dengan elemen ii ialah hasil bagi qubit rantai ii.

Anda mesti mendapatkan semula keputusan dalam sesi yang sama yang menghantar job, kerana QiskitIBMRuntime.jl belum boleh mencari job melalui ID-nya (qiskit-ibm-runtime-c issue #28). Jika sesuatu job gagal, sel mengeluarkan amaran dan diteruskan. Jika sesi berhenti, jalankan semula Langkah 1 hingga 3. Menjalankan semula sel hanya menghantar tetapan yang hasilnya tiada. Dengan use_saved_data = true, sel tidak menghantar apa-apa.

outcome_file(r) = joinpath(run_directory, "outcomes", "setting_$(lpad(r, 4, '0')).npz")

"Save the outcomes of setting `r` as a (shots × N) matrix of 0/1 values."
function save_outcomes(r, job)
try
samples = get_sampler_job_results(job, service)
bits = UInt8.(permutedims(reduce(hcat, samples)))
npzwrite(outcome_file(r), Dict("bits" => bits))
catch err
@warn "Setting $r failed and was not saved; run this cell again to resubmit it" err
end
end

if use_saved_data
println("Using the saved ibm_fez measurements; no jobs submitted")
else
backend_name = "ibm_fez"
service = Service() # uses the credentials saved on this computer
backend = only(b for b in backend_search(service) if b.name == backend_name)
open(joinpath(run_directory, "metadata.json"), "w") do io
JSON.print(io, Dict("backend" => backend_name, "N" => N_hw, "depth" => 1, "settings" => NU_hw,
"shots" => NM_hw, "chain" => chain_physical), 2)
end
in_flight = []
for r in 1:NU_hw
isfile(outcome_file(r)) && continue
push!(in_flight, (r, run_sampler_job(service, backend, circuits[r], NM_hw)))
length(in_flight) >= 32 && save_outcomes(popfirst!(in_flight)...)
end
foreach(job -> save_outcomes(job...), in_flight)
println("Saved outcomes: ", count(r -> isfile(outcome_file(r)), 1:NU_hw), " of ", NU_hw, " settings")
end
Using the saved ibm_fez measurements; no jobs submitted

Langkah 4: Pasca-proses dan kembalikan keputusan dalam format klasik yang dikehendaki​

Langkah ini hanya membaca data tersimpan: larian ibm_fez yang dimuat turun jika use_saved_data benar, atau jika tidak, fail yang ditulis oleh Langkah 3. Oleh itu, anda boleh menjalankannya dalam sesi baharu tanpa menghantar job (jalankan sel Setup, sel use_saved_data, dan Langkah 1 dahulu). Fail yang dimuat turun menyimpan 96 hasil bagi setiap tembakan yang dipadatkan dalam 12 bait, bit paling bererti dahulu, jadi pemuat menyahpadatkannya. RandomMeas.jl melabelkan hasil 1 dan 2, jadi pemuat juga menambah 1 pada setiap bit.

"Build a `MeasurementGroup` from the angles and a function `outcomes(r)` that returns
the (shots × N) 0/1 outcomes of setting `r`."
function measurement_group(angles, outcomes)
settings_count, n = size(angles, 1), size(angles, 2)
sites = siteinds("Qubit", n)
data = map(1:settings_count) do r
rotations = Array{ComplexF64}(undef, n, 2, 2)
for i in 1:n
rotations[i, :, :] = u3_matrix(angles[r, i, :]...)
end
MeasurementData(Int.(outcomes(r)) .+ 1;
measurement_setting=LocalUnitaryMeasurementSetting(rotations; site_indices=sites))
end
MeasurementGroup(data)
end

if use_saved_data
packed = saved_run["outcomes"] # settings × shots × 12 bytes
# Bit i of a shot is in byte (i - 1) ÷ 8 + 1, most significant bit first
unpack(r) = [(packed[r, s, (i - 1) ÷ 8 + 1] >> (7 - (i - 1) % 8)) & 0x01
for s in 1:size(packed, 2), i in 1:N_hw]
group_hw = measurement_group(angles, unpack)
else
group_hw = measurement_group(angles, r -> npzread(outcome_file(r))["bits"])
end
println(group_hw.NU, " settings × ", group_hw.NM, " shots on ", group_hw.N, " qubits")
1024 settings ×
1024 shots on 96 qubits

Sebelum mempelajari, semak data. Qubit yang rosak atau gate yang ditentukur dengan buruk menjadikan keadaan terukur jauh lebih bercampur di sekelilingnya, dan boleh menyebabkan pembelajar menyimpang. Ketulenan beberapa qubit berjiran ialah penanda aras bebas-model bagi hingar ini: fungsi get_purity daripada RandomMeas.jl menganggar tr ρA2\mathrm{tr}\,\rho_A^2 bagi subsistem AA dengan membandingkan pasangan tembakan daripada tetapan yang sama. Kira entropi Rényi-2 S2=−log⁡2tr ρA2S_2=-\log_2\mathrm{tr}\,\rho_A^2 bagi setiap tetingkap enam qubit berjiran, dan bandingkannya dengan tetingkap yang sama bagi keadaan unggul. Nilai unggul bukan sifar, kerana setiap tetingkap terjalin dengan bahagian rantai yang lain; hingar meningkatkannya, dan qubit yang rosak menolak setiap tetingkap yang mengandunginya ke arah maksimum enam.

ideal_hw = kicked_ising_reference(N_hw, 1)
width = 6
starts = 1:N_hw - width + 1
window_entropy(rho, w) = -log2(mpo_overlap(segment_mpo(rho, w), segment_mpo(rho, w)))
measured_entropy = [-log2(get_purity(group_hw, collect(j:j + width - 1))) for j in starts]
ideal_entropy = [window_entropy(ideal_hw, j:j + width - 1) for j in starts]
worst = argmax(measured_entropy)
println("S₂ of six-qubit windows: median ", round(median(measured_entropy), digits=2), "; highest ",
round(measured_entropy[worst], digits=2), " (chain positions ", worst, " to ", worst + width - 1, ")")
println("Ideal state: ", round(minimum(ideal_entropy), digits=2), " to ", round(maximum(ideal_entropy), digits=2))
plot(starts, measured_entropy; marker=:circle, markersize=2, label="measured",
xlabel="first chain position of the window", ylabel="S₂ of six qubits", ylims=(0, width),
legend=:topright, size=(800, 280), left_margin=5Plots.mm, bottom_margin=5Plots.mm)
plot!(starts, ideal_entropy; linestyle=:dash, label="ideal state")
S₂ of six-qubit windows: median 0.9
; highest 1.43 (chain positions 30 to 35)
Ideal state: 0.19 to 0.39

Output of the previous code cell

Setiap tetingkap lebih bercampur daripada keadaan unggul, kira-kira setengah bit hingga satu bit, dan bahagian paling bising berada sekitar kedudukan rantai 30 hingga 35. Tiada tetingkap yang menghampiri maksimum enam, jadi tiada qubit yang rosak, dan analisis menggunakan keseluruhan rantai 96 qubit. Jika sesetengah tetingkap mempunyai entropi hampir enam, anda akan membuang qubit yang dikongsi oleh tetingkap tersebut dan mempelajari bahagian rantai yang paling panjang tanpanya.

Ketulenan yang sama menentukan prior CRM. Bagi setiap tetingkap, fitted_prior mengambil keadaan unggul dan memadankan kekuatan depolarisasi setempat supaya ketulenannya sepadan dengan ketulenan yang diukur dalam tetapan latihan, seperti dalam kertas kerja itu.

Fungsi learn_and_validate dalam sel berikut melakukan baki analisis. Ia mempelajari model daripada tetapan latihan, kemudian menganggar Fmax⁡\mathcal{F}_{\max} dan S2S_2 pada tetapan ujian bagi NN qubit pertama rantai, dalam langkah 12. Ini ialah kuantiti dalam Rajah 1(c,d) kertas kerja itu. Keadaan unggul dinilai pada data ujian yang sama sebagai garis asas.

Sel menjalankan fungsi dengan ℓ=2\ell=2 dan kemudian mengulanginya dengan ℓ=1\ell=1 dan ℓ=0\ell=0 untuk melihat sejauh mana saiz tetingkap pembelajaran penting. Dimensi ikatan paling banyak 4ℓ4^\ell, jadi ℓ=0\ell=0 mempelajari keadaan hasil darab: setiap qubit bersendirian, tanpa korelasi antara qubit.

function learn_and_validate(group; ideal, ell=2, k=3, sizes=12:12:group.N, seed=20260921, train_fraction=0.5)
split = split_settings(group; seed, train_fraction)
prior = fitted_prior(ideal, split.train)
marginals = training_marginals(split.train; ell, prior)
fit = learn_mpo(marginals, group.N; ell, maxbond=min(4, 4^ell), sweeps=20)
last(fit.history).purity <= 1 ||
@warn "The model has purity above one, so the fit diverged. Collect more settings or shots."
statistics = afc_statistics(split.test, k; prior)
learned = afc_prefix_curve(fit.model, statistics, split.test.NU; k, sizes)
baseline = afc_prefix_curve(ideal, statistics, split.test.NU; k, sizes)
model_entropy = [-log2(mpo_overlap(prefix_mpo(fit.model, n), prefix_mpo(fit.model, n))) for n in sizes]
(; ell, fit, split, learned, baseline, model_entropy)
end

function plot_validation(results, title)
n = [r.n for r in first(results).learned]
# Marker, size, and line style per ℓ. The ℓ = 1 squares are small enough to sit inside the
# ℓ = 2 circles, so both stay visible where the two curves overlap.
style = Dict(2 => (:circle, 7, :solid), 1 => (:rect, 3.5, :dash), 0 => (:utriangle, 5, :dot))
fidelity = plot(yscale=:log10, ylims=(1e-6, 1.5), legend=:bottomleft, xlabel="number of qubits N",
ylabel="held-out F_max", title=title)
entropy = plot(xlabel="number of qubits N", ylabel="Rényi-2 entropy S₂", legend=:topleft)
held_out = first(results).learned
# Draw every error bar before any marker, so the bars stay behind the symbols
for (color, result) in enumerate(results)
scatter!(fidelity, n, [r.fidelity for r in result.learned]; yerror=[r.fidelity_sem for r in result.learned],
markersize=0, markerstrokecolor=color, label="")
end
scatter!(entropy, n, [r.entropy for r in held_out]; yerror=[r.entropy_sem for r in held_out],
markersize=0, markerstrokecolor=:black, label="")
for (color, result) in enumerate(results)
marker, markersize, linestyle = style[result.ell]
label = "learned model, ℓ = $(result.ell)"
plot!(fidelity, n, [r.fidelity for r in result.learned]; color, marker, markersize, linestyle,
markerstrokewidth=0, label)
plot!(entropy, n, result.model_entropy; color, linestyle, linewidth=2, label)
end
plot!(fidelity, n, [r.fidelity for r in first(results).baseline]; marker=:diamond, markersize=5,
linestyle=:dashdot, color=:black, label="ideal state")
scatter!(entropy, n, [r.entropy for r in held_out]; marker=:circle, markersize=4, color=:black,
label="held-out AFC estimate")
plot(fidelity, entropy; layout=(1, 2), size=(1000, 400), left_margin=7Plots.mm, bottom_margin=7Plots.mm)
end

function summarize(result)
final = last(result.learned)
println("ℓ = ", result.ell, ", N = ", final.n, ": held-out F_max = ", round(final.fidelity, sigdigits=3), " ± ",
round(final.fidelity_sem, sigdigits=2), " (ideal state: ", round(last(result.baseline).fidelity, sigdigits=2), ")")
println(" S₂ = ", round(final.entropy, digits=2), " ± ", round(final.entropy_sem, digits=2),
" held out; ", round(last(result.model_entropy), digits=2), " from the model")
lowest = minimum(minimum(eigvals(Hermitian(operator_from_coefficients(local_coefficients(result.fit.model, w)))))
for w in unique(learning_windows(final.n, max(result.ell, 1))))
println(" Most negative eigenvalue in any learning window: ", round(lowest, digits=4))
end

results_hw = [learn_and_validate(group_hw; ideal=ideal_hw, ell) for ell in (2, 1, 0)]
foreach(summarize, results_hw)
plot_validation(results_hw, "ibm_fez, 96-qubit chain")
ℓ = 2
, N = 96: held-out F_max = 0.591 ± 0.1 (ideal state: 0.0035)
S₂ = 10.04 ± 0.28 held out; 10.21 from the model
Most negative eigenvalue in any learning window: -0.0523
ℓ = 1, N = 96: held-out F_max = 0.554 ± 0.094 (ideal state: 0.0035)
S₂ = 10.04 ± 0.28 held out; 10.26 from the model
Most negative eigenvalue in any learning window: -0.0215
ℓ = 0, N = 96: held-out F_max = 6.18e-6 ± 1.1e-6 (ideal state: 0.0035)
S₂ = 10.04 ± 0.28 held out; 32.01 from the model
Most negative eigenvalue in any learning window: 0.0012

Output of the previous code cell

Keputusan menghasilkan semula kedua-dua dakwaan kertas kerja itu pada pemproses yang berbeza:

  • Model menerangkan data jauh lebih baik daripada keadaan unggul. Pada N=96N=96, Fmax⁡\mathcal{F}_{\max} tertahan bagi model ℓ=2\ell=2 ialah 0.59 ± 0.10, berbanding 0.0035 bagi keadaan unggul. Kertas kerja itu melaporkan kira-kira 0.75 pada ibm_brisbane.

  • Entropi model sepadan dengan data ujian pada setiap NN. Pada N=96N=96, ia ialah 10.2 daripada model dan 10.0 ± 0.3 daripada data ujian, atau S2/N≈0.10S_2/N\approx 0.10, berbanding 0.14 hingga 0.15 pada ibm_brisbane yang lebih lama.

Perbandingan saiz tetingkap menunjukkan di mana maklumat berada. Dengan ℓ=1\ell=1, model hampir sebaik itu (Fmax⁡=0.55±0.09\mathcal{F}_{\max}=0.55\pm0.09), jadi bagi data ini, korelasi melangkaui beberapa qubit menambah sedikit sahaja. Dengan ℓ=0\ell=0, keadaan hasil darab terlepas keterjalinan antara qubit berjiran: entropinya meningkat kepada 32 dan bukannya 10, dan Fmax⁡\mathcal{F}_{\max}-nya jatuh lebih cepat lagi daripada keadaan unggul, kepada 6×10−66\times10^{-6} pada N=96N=96.

Ingat batasan berikut apabila anda membaca nombor ini:

  • Pembahagian latihan. Bar ralat hanya meliputi ralat statistik data ujian. Pembahagian rawak lain bagi tetapan yang sama memberikan Fmax⁡\mathcal{F}_{\max} antara 0.49 dan 0.59 pada N=96N=96 bagi ℓ=2\ell=2.

  • Sapuan akhir. Pembelajar sentiasa mengembalikan model daripada sapuan akhir, jadi data ujian tidak pernah mempengaruhi model.

  • Kepositifan. Model tidak dikekang supaya positif separa tentu; nilai eigen paling negatifnya dalam tetingkap pembelajaran kira-kira −0.05-0.05. Oleh itu, Fmax⁡\mathcal{F}_{\max} dan S2S_2-nya menerangkan sebuah pengendali, bukan sifat tersahih bagi keadaan fizikal.

  • Pemfaktoran. Setiap anggaran tertahan bergantung pada andaian AFC, yang tidak dapat disahkan oleh pengukuran itu sendiri.

Langkah seterusnya​

Cadangan
  • Ulang eksperimen pada kedalaman dua dengan parameter kertas kerja itu bagi kedalaman tersebut (ℓ=3\ell=3 dan dimensi ikatan maksimum 8), dan tentukan berapa banyak tetapan pengukuran yang diperlukan oleh pembelajar.

  • Belajar dengan kemas kini dua-tapak sebagai ganti (update=:two_site dalam training_marginals dan learn_mpo), yang memangkas dimensi ikatan selepas setiap langkah, dan lihat bagaimana ia berfungsi dengan tetapan latihan yang lebih sedikit.

  • Belajar tanpa prior CRM (prior=nothing) dan bandingkan kesetiaan tertahan.

  • Gunakan analisis yang sama pada pengukuran ibm_brisbane yang diterbitkan oleh pengarang.

  • Baca suplemen kertas kerja itu untuk terbitan kemas kini dan penganggar AFC.

  • Terokai protokol pengukuran rawak yang lain dalam contoh RandomMeas.jl.

Rujukan​

  1. M. Votto, M. Ljubotina, C. Lancien, J. I. Cirac, P. Zoller, M. Serbyn, L. Piroli, and B. Vermersch, "Learning mixed quantum states in large-scale experiments", Phys. Rev. Lett. 136, 090801 (2026). arXiv:2507.12550

  2. A. Elben, S. T. Flammia, H.-Y. Huang, R. Kueng, J. Preskill, B. Vermersch, and P. Zoller, "The randomized measurement toolbox", Nat. Rev. Phys. 5, 9 (2023). arXiv:2203.11374

  3. H.-Y. Huang, R. Kueng, and J. Preskill, "Predicting many properties of a quantum system from very few measurements", Nat. Phys. 16, 1050 (2020). arXiv:2002.08953

  4. A. Elben and B. Vermersch, "RandomMeas.jl: A Julia package for randomized measurements in quantum devices", Quantum 10, 2086 (2026). arXiv:2509.12749

  5. B. Vermersch, A. Rath, B. Sundar, C. Branciard, J. Preskill, and A. Elben, "Enhanced estimation of quantum properties with common randomized measurements", PRX Quantum 5, 010352 (2024). arXiv:2304.12292

  6. H. Zou, "Randomized measurements of a 96-qubit kicked-Ising state on ibm_fez", Zenodo (2026). doi:10.5281/zenodo.24116174